Transparency Class

Life With Nate Nate's Poetry Page Resume (PDF)Nate's Code ASP.NET 2.0/3.5 VB.NET 2.0/3.5 BitStringConverter Fraction LargeDecimal LDFraction Transparency Just For Fun Windows Phone 7

Description

	The Transparency class is a class used to add transparency to a System.Drawing.Bitmap object. This is done by assigning a custom System.Drawing.Imaging.ColorPalette to the Bitmap's Palette property. The MakeTransparent() function of the Transparency class can be used not only to add transparency to an image, but to insure that the colors used when creating the image are the colors used when saving the image. This can often be necessary because when saving using the System.Drawing.Imaging.ImageFormat.Gif format, a predefined palette is used, causing a slightly different color or even a checkerboard pattern of multiple colors to replace the colors you used when creating your image.

Example

The following three images were generated by the same code. The first is saved without modification, the second customizes the palette but does not make it transparent, and the third modifies the palette and makes the image transparent. The statements used to save these images is listed below.


Unmodified Image	Modified Palette	Transparent Image

bmp.Save(Response.OutputStream, ImageFormat.Gif)
Transparency.MakeTransparent(bmp, Color.Empty).Save(Response.OutputStream, ImageFormat.Gif)
Transparency.MakeTransparent(bmp, Color.Blue).Save(Response.OutputStream, ImageFormat.Gif)

Properties & Methods

	MakeTransparent(ByVal oldbmp As Bitmap, ByVal transparentcolor As Color) As BitmapUsed to make a custom palette that contains the colors used in the original Bitmap rather than the predefined palette, and optionally make one color transparent. The number of colors is limited to 256 (one of which must be the color that will be made transparent if adding transparency).
	oldbmp - The Bitmap to be modified
transparentcolor - The Color that you would like to make transparent. If you would like to have the palette corrected but do not need or want any colors made transparent, use the value Color.Empty.

	ColorCount(ByVal bmp As Bitmap) As IntegerUsed to determine how many colors are used in the Bitmap. If you have used any methods or techniques when creating your Bitmap that dynamically determine colors, or use multiple colors, this can help you determine whether or not it can be used with the MakeTransparent function.
	bmp - The Bitmap of which to count the Colors

	InPalette(ByVal palette As ColorPalette, ByVal maxindex As Byte, ByVal colortofind As Color) As IntegerUsed to return the index of the specified Color in the palette. The possible return values are 0 through 255 or -1 if the color does not exist in the palette. This function is primarily used internally, but may be accessed as a Shared function as well.
	palette - The ColorPalette to be searched
maxindex - The maximum index to search. If you would like to search the entire palette, you may enter a value of 255
colortofind - The color to return the index of

Source Code

Transparency.vb:

Imports System.Drawing
Imports System.Drawing.Imaging
Namespace NathanSokalski
	Public Class Transparency
		Public Shared Function MakeTransparent(ByVal oldbmp As Bitmap, ByVal transparentcolor As Color) As Bitmap
			Dim bmp As New Bitmap(oldbmp.Width, oldbmp.Height, PixelFormat.Format8bppIndexed)
			Dim palette As ColorPalette = bmp.Palette
			Dim nextindex As Byte = 0
			Dim bmpdata As BitmapData = bmp.LockBits(New Rectangle(0, 0, oldbmp.Width, oldbmp.Height), ImageLockMode.WriteOnly, PixelFormat.Format8bppIndexed)
			Dim index As Integer
			For i As Integer = 0 To 255
				palette.Entries(i) = Color.Empty
			Next
			For y As Integer = 0 To oldbmp.Height - 1
				For x As Integer = 0 To oldbmp.Width - 1
					'Get the palette index of the current pixel
					index = Transparency.InPalette(palette, nextindex - 1, oldbmp.GetPixel(x, y))
					'If the color is not in the palette, add it at the next unused index
					If index = -1 Then
						palette.Entries(nextindex) = oldbmp.GetPixel(x, y)
						index = nextindex
						nextindex += CByte(1)
					End If
					'Set the pixel to the proper index
					System.Runtime.InteropServices.Marshal.WriteByte(bmpdata.Scan0, y * bmpdata.Stride + x, CByte(index))
				Next
			Next
			bmp.UnlockBits(bmpdata)
			'If the specified transparent color is included in the palette, change that color to transparent
			If transparentcolor <> Color.Empty AndAlso Transparency.InPalette(palette, nextindex - CByte(1), transparentcolor) <> -1 Then palette.Entries(Transparency.InPalette(palette, nextindex - CByte(1), transparentcolor)) = Color.FromArgb(0, 0, 0, 0)
			bmp.Palette = palette
			Return bmp
		End Function

		'Returns number of colors in bitmap
		Public Shared Function ColorCount(ByVal bmp As Bitmap) As Integer
			Dim palette As New Collections.ObjectModel.Collection(Of Integer)
			Dim currcolor As Integer
			For y As Integer = 0 To bmp.Height - 1
				For x As Integer = 0 To bmp.Width - 1
					currcolor = bmp.GetPixel(x, y).ToArgb()
					If Not palette.Contains(currcolor) Then palette.Add(currcolor)
				Next
			Next
			Return palette.Count
		End Function

		'Returns index of color in palette or -1
		Private Shared Function InPalette(ByVal palette As ColorPalette, ByVal maxindex As Integer, ByVal colortofind As Color) As Integer
			For i As Integer = 0 To maxindex
				If palette.Entries(i).ToArgb() = colortofind.ToArgb() Then Return CInt(i)
			Next
			Return -1
		End Function
	End Class
End Namespace

Remarks

The Transparency class is intended to be used with images that will be saved as PixelFormat.Gif. If you are unsure of the number of colors used in your image, be sure to use the ColorCount function. If your image has more than 256 colors, you may receive an error, and be sure to remember that one of those 256 colors must be the same as the transparentcolor in order to add transparency to your image.

I would also like to give a special thank you to Yosi K. Karl for helping me find and fix a bug in the Transparency class.