RotatedTextImage Control

RotatedTextImage.vb:
Namespace NathanSokalski
	<System.Drawing.ToolboxBitmap(GetType(ToolboxIcons), "RotatedTextImage.bmp")> _
	Public Class RotatedTextImage : Inherits System.Web.UI.WebControls.Image
		'The following code must be included in a Web Application's Web.config in order to use the RotatedTextHandler, which is used by the RotatedTextImage:
		'<configuration>
		'	<system.web>
		'		<httpHandlers>
		'			<add path="*/RotatedTextHandler.ashx" verb="*" type="NathanSokalski.RotatedTextHandler,NathanSokalski" validate="false"/>
		'		</httpHandlers>
		'	</system.web>
		'</configuration>
		Private _rotation As Double = 0
		Private _text As String = String.Empty
		Private _fontcolor As System.Drawing.Color = Drawing.Color.Black
		Private _backgroundstyle As NathanSokalski.RotatedTextHandler.BackgroundStyle = NathanSokalski.RotatedTextHandler.BackgroundStyle.Transparent
		Private _background As System.Drawing.Color = Drawing.Color.White
		Private _fontstyle As New System.Drawing.FontStyle
		Private _fontname As String = "Arial"
		Private _size As Single = 24

		<DefaultValue(0), _
		Description("The number of degrees clockwise the text is rotated")> _
		Public Property Rotation() As Double
			Get
				Return Me._rotation
			End Get
			Set(ByVal value As Double)
				Me._rotation = value
			End Set
		End Property
		<Description("The text use to generate the image")> Public Property Text() As String
			Get
				Return Me._text
			End Get
			Set(ByVal value As String)
				Me._text = value
			End Set
		End Property
		<DefaultValue("Black"), _
		Description("The color used for the text")> _
		Public Property FontColor() As System.Drawing.Color
			Get
				Return Me._fontcolor
			End Get
			Set(ByVal value As System.Drawing.Color)
				Me._fontcolor = value
			End Set
		End Property
		<DefaultValue("Transparent"), _
		Description("A member of the NathanSokalski.RotatedTextHandler.BackgroundStyle enumeration specifying what part of the background should be colored")> _
		Public Property BackgroundStyle() As NathanSokalski.RotatedTextHandler.BackgroundStyle
			Get
				Return Me._backgroundstyle
			End Get
			Set(ByVal value As NathanSokalski.RotatedTextHandler.BackgroundStyle)
				Me._backgroundstyle = value
			End Set
		End Property
		<DefaultValue("White"), _
		Description("The background color used when the text has a background")> _
		Public Property Background() As System.Drawing.Color
			Get
				Return Me._background
			End Get
			Set(ByVal value As System.Drawing.Color)
				Me._background = value
			End Set
		End Property
		<DefaultValue(False), _
		Description("A Boolean value specifying whether the text is bold")> _
		Public Property Bold() As Boolean
			Get
				Return (Me._fontstyle And System.Drawing.FontStyle.Bold) = System.Drawing.FontStyle.Bold
			End Get
			Set(ByVal value As Boolean)
				If value Then Me._fontstyle = Me._fontstyle Or System.Drawing.FontStyle.Bold Else Me._fontstyle = Me._fontstyle And Not System.Drawing.FontStyle.Bold
			End Set
		End Property
		<DefaultValue(False), _
		Description("A Boolean value specifying whether the text is italic")> _
		Public Property Italic() As Boolean
			Get
				Return (Me._fontstyle And System.Drawing.FontStyle.Italic) = System.Drawing.FontStyle.Italic
			End Get
			Set(ByVal value As Boolean)
				If value Then Me._fontstyle = Me._fontstyle Or System.Drawing.FontStyle.Italic Else Me._fontstyle = Me._fontstyle And Not System.Drawing.FontStyle.Italic
			End Set
		End Property
		<DefaultValue(False), _
		Description("A Boolean value specifying whether the text is strikeout")> _
		Public Property Strikeout() As Boolean
			Get
				Return (Me._fontstyle And System.Drawing.FontStyle.Strikeout) = System.Drawing.FontStyle.Strikeout
			End Get
			Set(ByVal value As Boolean)
				If value Then Me._fontstyle = Me._fontstyle Or System.Drawing.FontStyle.Strikeout Else Me._fontstyle = Me._fontstyle And Not System.Drawing.FontStyle.Strikeout
			End Set
		End Property
		<DefaultValue(False), _
		Description("A Boolean value specifying whether the text is underlined")> _
		Public Property Underline() As Boolean
			Get
				Return (Me._fontstyle And System.Drawing.FontStyle.Underline) = System.Drawing.FontStyle.Underline
			End Get
			Set(ByVal value As Boolean)
				If value Then Me._fontstyle = Me._fontstyle Or System.Drawing.FontStyle.Underline Else Me._fontstyle = Me._fontstyle And Not System.Drawing.FontStyle.Underline
			End Set
		End Property
		<DefaultValue("Arial"), _
		Description("The name of the font used to generate the image")> _
		Public Property FontName() As String
			Get
				Return Me._fontname
			End Get
			Set(ByVal value As String)
				Me._fontname = value
			End Set
		End Property
		<DefaultValue(24), _
		Description("The size of the text")> _
		Public Property Size() As Single
			Get
				Return Me._size
			End Get
			Set(ByVal value As Single)
				Me._size = value
			End Set
		End Property
		<Browsable(False)> Public Overrides Property ImageUrl() As String
			Get
				Return MyBase.ImageUrl
			End Get
			Set(ByVal value As String)
				MyBase.ImageUrl = value
			End Set
		End Property

		Private Sub RotatedTextImage_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.PreRender
			If Not Me.Page.ClientScript.IsClientScriptBlockRegistered("RotatedTextImagePreload") Then Me.Page.ClientScript.RegisterClientScriptBlock(Me.GetType(), "RotatedTextImagePreload", "var RotatedTextImagePreload=new Image();", True)
			Me.Page.ClientScript.RegisterClientScriptBlock(Me.GetType(), String.Concat("RotatedTextImagePreload_", Me.ClientID), String.Format("RotatedTextImagePreload.src='{0}';", RotatedTextImage.GetImageUrl(Me._rotation, Me._text, Me._fontcolor, Me._backgroundstyle, Me._background, Me._fontstyle, Me._fontname, Me._size)), True)
		End Sub

		Protected Overrides Sub Render(ByVal writer As System.Web.UI.HtmlTextWriter)
			Me.ImageUrl = RotatedTextImage.GetImageUrl(Me._rotation, Me._text, Me._fontcolor, Me._backgroundstyle, Me._background, Me._fontstyle, Me._fontname, Me._size)
			MyBase.Render(writer)
		End Sub

		Public Shared Function GetImageUrl(ByVal rotangle As Double, ByVal txt As String, ByVal fntcolor As System.Drawing.Color, ByVal bgstyle As NathanSokalski.RotatedTextHandler.BackgroundStyle, ByVal bgcolor As System.Drawing.Color, ByVal bold As Boolean, ByVal italic As Boolean, ByVal strikeout As Boolean, ByVal underline As Boolean, ByVal fntname As String, ByVal fntsize As Single) As String
			Dim imgurl As New System.Collections.Generic.List(Of String)
			Dim tempstyle As New System.Drawing.FontStyle
			If bold Then tempstyle = tempstyle Or System.Drawing.FontStyle.Bold
			If italic Then tempstyle = tempstyle Or System.Drawing.FontStyle.Italic
			If strikeout Then tempstyle = tempstyle Or System.Drawing.FontStyle.Strikeout
			If underline Then tempstyle = tempstyle Or System.Drawing.FontStyle.Underline
			Return NathanSokalski.RotatedTextImage.GetImageUrl(rotangle, txt, fntcolor, bgstyle, bgcolor, tempstyle, fntname, fntsize)
		End Function
		Public Shared Function GetImageUrl(ByVal rotangle As Double, ByVal txt As String, ByVal fntcolor As System.Drawing.Color, ByVal bgstyle As NathanSokalski.RotatedTextHandler.BackgroundStyle, ByVal bgcolor As System.Drawing.Color, ByVal fntstyle As System.Drawing.FontStyle, ByVal fntname As String, ByVal fntsize As Single) As String
			Dim imgurl As New System.Collections.Generic.List(Of String)
			imgurl.Add(String.Format("Rotation={0}", rotangle))
			imgurl.Add(String.Format("Text={0}", HttpContext.Current.Server.UrlEncode(txt)))
			imgurl.Add(String.Format("FontColor={0}", HttpContext.Current.Server.UrlEncode(System.Drawing.ColorTranslator.ToHtml(fntcolor))))
			imgurl.Add(String.Format("BackgroundStyle={0}", CByte(bgstyle)))
			If bgstyle <> NathanSokalski.RotatedTextHandler.BackgroundStyle.Transparent Then imgurl.Add(String.Format("Background={0}", HttpContext.Current.Server.UrlEncode(System.Drawing.ColorTranslator.ToHtml(bgcolor))))
			imgurl.Add(String.Format("FontStyle={0}", CInt(fntstyle)))
			imgurl.Add(String.Format("FontName={0}", HttpContext.Current.Server.UrlEncode(fntname)))
			imgurl.Add(String.Format("Size={0}", fntsize))
			Return String.Format("RotatedTextHandler.ashx?{0}", String.Join("&", imgurl.ToArray()))
		End Function
	End Class
End Namespace