RestrictInputTextBox Control

Description

	The RestrictInputTextBox is a simple control that inherits from the standard TextBox. The RestrictInputTextBox does nothing more than add an onkeypress JavaScript event handler that prevents users from typing certain characters in the TextBox. This can be useful when asking a user to enter a price without the dollar sign, a phone number using only the digits, a password that only contains certain characters, or even something as simple as making sure they only enter a number for certain fields. The Tab and Backspace keys are always allowed, so that you do not need to worry about preventing the user from editing their text or tabbing to the next field.

Example

ValidInput Enumeration	Accepted Characters
ValidInput.None
ValidInput.AllChars	Any Character
ValidInput.Letters	[A-Z],[a-z]
ValidInput.AlphaNumericDigits	[A-Z],[a-z],[0-9]
ValidInput.AlphaNumericNumbers	[A-Z],[a-z],[0-9],.,-
ValidInput.Uppercase	[A-Z]
ValidInput.Lowercase	[a-z]
ValidInput.Digits	[0-9]
ValidInput.Integers	[0-9],-
ValidInput.Numbers	[0-9],.,-
ValidInput.PositiveNumbers	[0-9],.
ValidInput.Hexadecimal	[0-9],[A-F],[a-f]
ValidInput.Binary	[0-1]
ValidInput.Octal	[0-7]
Server Tag
<NJS:RestrictInputTextBox runat="server" Accepted="AlphaNumericDigits" Specific="_." EnableViewState="false"/>
<NJS:RestrictInputTextBox runat="server" Accepted="AllChars" Invalid=""'" EnableViewState="false"/>
<NJS:RestrictInputTextBox runat="server" Accepted="None" Specific="AEIOUaeiou" EnableViewState="false"/>
<NJS:RestrictInputTextBox runat="server" Accepted="Hexadecimal" Specific="#" Invalid="abcdef" EnableViewState="false"/>

Properties & Methods

	RestrictInputTextBoxThe RestrictInputTextBox inherits all of the properties and methods in the standard TextBox, and is used to prevent the user from typing certain characters.
	Accepted - The predefined group of characters from the ValidInput enumeration (Default="AllChars")
Specific - A String containing the characters to be added to the selected predefined group of characters (Default=String.Empty)
Invalid - A String containing the characters to be removed from the selected predefined group of characters (Default=String.Empty)

	ValidInput As ByteAn enumeration used to specify a predefined group of accepted characters.
	None - Accepts only Tab and Backspace. This option is intended to be used only if you want to completely customize the list of accepted characters
AllChars - Accepts all characters. Intended for use when there are only a few characters you do not want to allow
Letters - Accepts [A-Z],[a-z]
AlphaNumericDigits - Accepts [A-Z],[a-z],[0-9]
AlphaNumericNumbers - Accepts [A-Z],[a-z],[0-9],.,-
Uppercase - Accepts [A-Z]
Lowercase - Accepts [a-z]
Digits - Accepts [0-9]
Integers - Accepts [0-9],-
Numbers - Accepts [0-9],.,-
PositiveNumbers - Accepts [0-9],.
Hexadecimal - Accepts [0-9],[A-F],[a-f]
Binary - Accepts [0-1]
Octal - Accepts [0-7]

Source Code

RestrictInputTextBox.vb:

Namespace NathanSokalski
	<System.Drawing.ToolboxBitmap(GetType(ToolboxIcons), "RestrictInputTextbox.bmp")> _
	Public Class RestrictInputTextBox : Inherits TextBox
		Private _accepted As ValidInput = ValidInput.AllChars
		Private _specific As String = String.Empty
		Private _invalid As String = String.Empty

		<DefaultValue("AllChars"), _
		Description("The predefined group of characters from the ValidInput enumeration that the user will be allowed to enter")> _
		Public Property Accepted() As ValidInput
			Get
				Return Me._accepted
			End Get
			Set(ByVal value As ValidInput)
				Me._accepted = value
			End Set
		End Property
		<Description("Any additional characters that the user will be allowed to enter")> Public Property Specific() As String
			Get
				Return Me._specific
			End Get
			Set(ByVal value As String)
				Me._specific = value
			End Set
		End Property
		<Description("Any characters the user should not be allowed to enter")> Public Property Invalid() As String
			Get
				Return Me._invalid
			End Get
			Set(ByVal value As String)
				Me._invalid = value
			End Set
		End Property

		Protected Overrides Sub AddAttributesToRender(ByVal writer As System.Web.UI.HtmlTextWriter)
			MyBase.AddAttributesToRender(writer)

			Const uppercase As String = "(typedchar>=65&&typedchar<=90)"
			Const lowercase As String = "||(typedchar>=97&&typedchar<=122)"
			Const digits As String = "||(typedchar>=48&&typedchar<=57)"
			Const negative As String = "||typedchar==45"
			Const decpoint As String = "||typedchar==46"
			Const allchars As String = "typedchar>=0"
			Dim keyvalidation As New System.Text.StringBuilder()

			'Create validation for a predefined group
			Select Case Accepted
				Case ValidInput.AllChars
					keyvalidation.Append(allchars)
				Case ValidInput.AlphaNumericDigits
					keyvalidation.Append(uppercase).Append(lowercase).Append(digits)
				Case ValidInput.AlphaNumericNumbers
					keyvalidation.Append(uppercase).Append(lowercase).Append(digits).Append(negative).Append(decpoint)
				Case ValidInput.Binary
					keyvalidation.Append("(typedchar==48||typedchar==49)")
				Case ValidInput.Digits
					keyvalidation.Append(digits)
				Case ValidInput.Hexadecimal
					keyvalidation.Append(digits).Append("||(typedchar>=65&&typedchar<=70)||(typedchar>=97&&typedchar<=102)")
				Case ValidInput.Integers
					keyvalidation.Append(digits).Append(negative)
				Case ValidInput.Letters
					keyvalidation.Append(uppercase).Append(lowercase)
				Case ValidInput.Lowercase
					keyvalidation.Append(lowercase)
				Case ValidInput.None
					'No predefined validation necessary for ValidInput.None
				Case ValidInput.Numbers
					keyvalidation.Append(digits).Append(negative).Append(decpoint)
				Case ValidInput.Octal
					keyvalidation.Append("(typedchar>=48&&typedchar<=55)")
				Case ValidInput.PositiveNumbers
					keyvalidation.Append(digits).Append(decpoint)
				Case ValidInput.Uppercase
					keyvalidation.Append(uppercase)
			End Select

			'Add extra validation for specific characters
			If Specific <> "" Then
				For Each acceptchar As Char In Specific.ToCharArray()
					keyvalidation.Append("||typedchar==").Append(AscW(acceptchar))
				Next
			End If

			'Add extra validation for invalid characters
			If Invalid <> "" Then
				If keyvalidation.ToString().StartsWith("||") Then keyvalidation.Remove(0, 2)
				keyvalidation.Insert(0, "(").Append(")")
				For Each acceptchar As Char In Invalid.ToCharArray()
					keyvalidation.Append("&&typedchar!=").Append(AscW(acceptchar))
				Next
			End If

			If Me.Page.Request.Browser.EcmaScriptVersion.Major >= 1 Then
				If keyvalidation.ToString().StartsWith("||") Then keyvalidation.Remove(0, 2)
				If keyvalidation.ToString().StartsWith("(&&") Then keyvalidation.Remove(1, 2)
				'TODO Make sure all necessary browsers are included
				Select Case Me.Page.Request.Browser.Browser.ToUpper()
					Case "IE"
						keyvalidation.Insert(0, "return (").Append(");").Replace("return ();", "return (false);")
						writer.AddAttribute("onkeypress", keyvalidation.Replace("typedchar", "event.keyCode").ToString())
					Case "FIREFOX", "FIREBIRD"
						keyvalidation.Insert(0, "return (event.charCode==0||(").Append("));").Replace("return (event.charCode==0||());", "return (event.charCode==0);")
						writer.AddAttribute("onkeypress", keyvalidation.Replace("typedchar", "event.charCode").ToString())
					Case Else
						keyvalidation.Insert(0, "return (").Append(");").Replace("return ();", "return (false);")
						writer.AddAttribute("onkeypress", keyvalidation.Replace("typedchar", "event.which").ToString())
				End Select
			End If
		End Sub

		Public Enum ValidInput As Byte
			None
			AllChars
			Letters	'[A-Z],[a-z]
			AlphaNumericDigits '[A-Z],[a-z],[0-9]
			AlphaNumericNumbers	'[A-Z],[a-z],[0-9],.,-
			Uppercase	'[A-Z]
			Lowercase	'[a-z]
			Digits '[0-9]
			Integers '[0-9],-
			Numbers	'[0-9],.,-
			PositiveNumbers	'[0-9],.
			Hexadecimal	'[0-9],[A-F],[a-f]
			Binary '[0-1]
			Octal	'[0-7]
		End Enum
	End Class
End Namespace

Remarks

Because the JavaScript keypress event is very different in most browsers and I do not have access to all of them for testing, please be aware that this could prevent the user from typing certain keys that were not meant to be blocked (usually keys such as backspace, tab, enter, etc.). If you plan on using this class for an important site, I would suggest doing a little testing on more browsers, and feel free to make any adjustments you feel necessary. RestrictInputTextBox does not prevent the user from copying & pasting invalid characters into the textbox, so if undesired characters could cause an error be sure to check the text on the server as well (This can be done using my RestrictInputValidator control). When using RestrictInputTextBox, be sure your users are aware of what characters they can use to avoid frustration or confusion when certain characters cannot be typed. This is especially important when using TextMode="Password", since the user cannot see what they have typed.