LengthValidator Control

Description

	The LengthValidator validates that the length of a TextBox is within a certain range. You may enter a value for the minimum, maximum, or both lengths. You are also given the option of having an error message that states the minimum and maximum lengths generated.

Example

Minimum 5 Characters:

Maximum 10 Characters:

Min 5, Max 10 Characters:

The following tags were used to create the validators used in the three examples above:

<NJS:LengthValidator runat="server" ControlToValidate="txtMinimum" Display="Dynamic" GenerateErrorMessage="true" MinimumLength="5" ValidationGroup="minimum"/>
<NJS:LengthValidator runat="server" ControlToValidate="txtMaximum" Display="Dynamic" GenerateErrorMessage="true" MaximumLength="10" ValidationGroup="maximum"/>
<NJS:LengthValidator runat="server" ControlToValidate="txtMaxMin" Display="Dynamic" GenerateErrorMessage="true" MinimumLength="5" MaximumLength="10" ValidationGroup="maxmin"/>

Properties & Methods

	LengthValidatorThe LengthValidator is used to validate the minimum and/or maximum number of characters in a TextBox.
	MaximumLength - The maximum number of characters allowed in the specified TextBox
MinimumLength - The minimum number of characters allowed in the specified TextBox
GenerateErrorMessage - Specifies whether a custom or generated error message should me used (default="True")

Source Code

LengthValidator.vb:

Namespace NathanSokalski
	<System.Drawing.ToolboxBitmap(GetType(ToolboxIcons), "LengthValidator.bmp"), _
	System.Web.UI.ToolboxData("<{0}:LengthValidator runat=""server""/>")> _
	Public Class LengthValidator : Inherits BaseValidator
		Dim maxlength As Integer = 0
		Dim minlength As Integer = 0
		Dim errmsg As Boolean = True

		<Description("The maximum number of characters allowed in a String")> Public Property MaximumLength() As Integer
			Get
				Return Me.maxlength
			End Get
			Set(ByVal value As Integer)
				Me.maxlength = value
			End Set
		End Property
		<Description("The minimum number of characters allowed in a String")> Public Property MinimumLength() As Integer
			Get
				Return Me.minlength
			End Get
			Set(ByVal value As Integer)
				Me.minlength = value
			End Set
		End Property
		<DefaultValue(True), _
		Description("A Boolean value specifying whether a custom or generated error message should me used")> _
		Public Property GenerateErrorMessage() As Boolean
			Get
				Return Me.errmsg
			End Get
			Set(ByVal value As Boolean)
				Me.errmsg = value
			End Set
		End Property

		Protected Overrides Function EvaluateIsValid() As Boolean
			Dim value As String = Me.GetControlValidationValue(Me.ControlToValidate)
			If Me.maxlength <> 0 Then
				Return value.Length <= Me.maxlength AndAlso value.Length >= Me.minlength
			Else
				Return value.Length >= Me.minlength
			End If
		End Function

		Private Sub Page_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.PreRender
			If Me.errmsg Then
				If Me.maxlength <> 0 AndAlso Me.minlength <> 0 Then
					Me.ErrorMessage = String.Format("You must enter between {0} and {1} characters.", Me.minlength, Me.maxlength)
				ElseIf Me.maxlength <> 0 AndAlso Me.minlength = 0 Then
					Me.ErrorMessage = String.Format("You may not enter more than {0} characters.", Me.maxlength)
				ElseIf Me.maxlength = 0 AndAlso Me.minlength <> 0 Then
					Me.ErrorMessage = String.Format("You must enter at least {0} characters.", Me.minlength)
				End If
			End If
			If Not Me.Page.ClientScript.IsClientScriptBlockRegistered("LengthValidatorIsValid") Then Me.Page.ClientScript.RegisterClientScriptBlock(Me.GetType(), "LengthValidatorIsValid", "function LengthValidatorIsValid(val){return document.getElementById(val.controltovalidate).value.length>=val.minimumlength&&(val.maximumlength==0||document.getElementById(val.controltovalidate).value.length<=val.maximumlength);}", True)
		End Sub

		Protected Overrides Sub AddAttributesToRender(ByVal writer As System.Web.UI.HtmlTextWriter)
			MyBase.AddAttributesToRender(writer)
			writer.AddAttribute("evaluationfunction", "LengthValidatorIsValid")
			writer.AddAttribute("minimumlength", CStr(Me.MinimumLength))
			writer.AddAttribute("maximumlength", CStr(Me.MaximumLength))
		End Sub
	End Class
End Namespace

Remarks

	The LengthValidator can be used to specify a minimum and/or maximum number of characters.