DateTimePickerTemplated Control

DateTimePickerTemplated.vb:
Namespace NathanSokalski
	Public Class DateTimePickerTemplated : Inherits System.Web.UI.WebControls.CompositeControl : Implements ICallbackEventHandler, IPostBackDataHandler
		Private _firstyear As Integer = 1950
		Private _lastyear As Integer = 2050
		Private _dayformat As DayNameStyle = DayNameStyle.None
		Private _monthformat As MonthNameStyle = MonthNameStyle.Abbreviated
		Private _layout As DTPLayout = DTPLayout.DateTime2Line
		Private _layouttemplate As ITemplate
		Private passedvalue As String = String.Empty
		Public Event SelectedDateTimeChanged As EventHandler

		<Description("The currently selected date and time")> Public Property SelectedDateTime() As DateTime
			Get
				If IsNothing(Me.ViewState("SelectedDateTime")) Then Return DateTime.Now Else Return CDate(Me.ViewState("SelectedDateTime"))
			End Get
			Set(ByVal value As DateTime)
				Me.ViewState("SelectedDateTime") = value
			End Set
		End Property
		<DefaultValue(1950), _
		Description("The first year displayed in the year DropDownList")> _
		Public Property FirstYear() As Integer
			Get
				Return Me._firstyear
			End Get
			Set(ByVal value As Integer)
				Me._firstyear = value
			End Set
		End Property
		<DefaultValue(2050), _
		Description("The last year displayed in the year DropDownList")> _
		Public Property LastYear() As Integer
			Get
				Return Me._lastyear
			End Get
			Set(ByVal value As Integer)
				Me._lastyear = value
			End Set
		End Property
		<DefaultValue("None"), _
		Description("The format of the day of the week in the day DropDownList")> _
		Public Property DayFormat() As DayNameStyle
			Get
				Return Me._dayformat
			End Get
			Set(ByVal value As DayNameStyle)
				Me._dayformat = value
			End Set
		End Property
		<DefaultValue("Abbreviated"), _
		Description("The format of the month in the month DropDownList")> _
		Public Property MonthFormat() As MonthNameStyle
			Get
				Return Me._monthformat
			End Get
			Set(ByVal value As MonthNameStyle)
				Me._monthformat = value
			End Set
		End Property
		<DefaultValue("DateTime2Line"), _
		Description("The layout of the date and/or time DropDownLists")> _
		Public Property Layout() As DTPLayout
			Get
				Return Me._layout
			End Get
			Set(ByVal value As DTPLayout)
				Me._layout = value
			End Set
		End Property
		<TemplateContainer(GetType(NathanSokalski.DateTimePickerTemplated)), PersistenceMode(PersistenceMode.InnerProperty)> Public Property LayoutTemplate() As ITemplate
			Get
				Return Me._layouttemplate
			End Get
			Set(ByVal value As ITemplate)
				Me._layouttemplate = value
			End Set
		End Property

		Protected Overrides Sub CreateChildControls()
			If IsNothing(Me._layouttemplate) Then
				Select Case Me.Layout
					Case DTPLayout.Date : Me._layouttemplate = New DateTimePickerTemplates.DateTemplate()
					Case DTPLayout.DateTime1Line : Me._layouttemplate = New DateTimePickerTemplates.DateTime1LineTemplate()
					Case DTPLayout.DateTime2Line : Me._layouttemplate = New DateTimePickerTemplates.DateTime2LineTemplate()
					Case DTPLayout.Time : Me._layouttemplate = New DateTimePickerTemplates.TimeTemplate()
					Case DTPLayout.TimeDate1Line : Me._layouttemplate = New DateTimePickerTemplates.TimeDate1LineTemplate()
					Case DTPLayout.TimeDate2Line : Me._layouttemplate = New DateTimePickerTemplates.TimeDate2LineTemplate()
				End Select
			End If
			Me._layouttemplate.InstantiateIn(Me)
		End Sub

		Public Function GetCallbackResult() As String Implements System.Web.UI.ICallbackEventHandler.GetCallbackResult
			'To Browser:	id|index|daycount|day1fmt|day2fmt|day3fmt|day4fmt|day5fmt|day6fmt|day7fmt
			'To Server:		yearval monthval dayval
			Dim ymdvalues() As String = Me.passedvalue.Split(" "c)
			Dim daycount As Integer = DateTime.DaysInMonth(CInt(ymdvalues(0)), CInt(ymdvalues(1)))
			Dim datedata As New Collections.Generic.List(Of String)
			Dim ctrls As IEnumerator = Me.Controls.GetEnumerator()
			While ctrls.MoveNext()
				If CType(ctrls.Current, Control).ID = "ddlDate" Then datedata.Add(CType(ctrls.Current, Control).ClientID) : Exit While
			End While
			datedata.Add((Math.Min(CInt(ymdvalues(2)), daycount) - 1).ToString())
			datedata.Add(daycount.ToString())
			For i As Integer = 1 To 7
				Select Case Me.DayFormat
					Case DayNameStyle.FirstLetter : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString().Substring(0, 1), " "))
					Case DayNameStyle.FirstTwoLetters : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString().Substring(0, 2), " "))
					Case DayNameStyle.Full : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString(), " "))
					Case DayNameStyle.None : datedata.Add(String.Empty)
					Case DayNameStyle.Short : datedata.Add(String.Concat(System.Globalization.DateTimeFormatInfo.CurrentInfo.AbbreviatedDayNames(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek), " "))
				End Select
			Next
			Return String.Join("|", datedata.ToArray())
		End Function

		Public Sub RaiseCallbackEvent(ByVal eventArgument As String) Implements System.Web.UI.ICallbackEventHandler.RaiseCallbackEvent
			Me.passedvalue = eventArgument
		End Sub

		Public Function LoadPostData(ByVal postDataKey As String, ByVal postCollection As System.Collections.Specialized.NameValueCollection) As Boolean Implements System.Web.UI.IPostBackDataHandler.LoadPostData
			Me.EnsureChildControls()
			Dim prevdatetime As DateTime = Me.SelectedDateTime
			Dim ddlYear = String.Empty, ddlMonth = String.Empty, ddlDate = String.Empty, ddlHour = String.Empty, ddlMinute = String.Empty, ddlSecond = String.Empty, ddlAMPM As String = String.Empty
			Dim yearvalue, monthvalue, dayvalue, hourvalue, minutevalue, secondvalue As Integer
			Dim temp As DropDownList
			Dim ctrls As IEnumerator = Me.Controls.GetEnumerator()

			'Get UniqueID values for existing controls
			While ctrls.MoveNext()
				If ctrls.Current.GetType() Is GetType(DropDownList) Then
					temp = CType(ctrls.Current, DropDownList)
					Select Case temp.ID
						Case "ddlYear" : ddlYear = temp.UniqueID
						Case "ddlMonth" : ddlMonth = temp.UniqueID
						Case "ddlDate" : ddlDate = temp.UniqueID
						Case "ddlHour" : ddlHour = temp.UniqueID
						Case "ddlMinute" : ddlMinute = temp.UniqueID
						Case "ddlSecond" : ddlSecond = temp.UniqueID
						Case "ddlAMPM" : ddlAMPM = temp.UniqueID
					End Select
				End If
			End While

			'Get postback values or DateTime.MinValue for each DateTime component
			If String.IsNullOrEmpty(ddlYear) OrElse IsNothing(postCollection(ddlYear)) Then yearvalue = DateTime.MinValue.Year Else yearvalue = CInt(postCollection(ddlYear))
			If String.IsNullOrEmpty(ddlMonth) OrElse IsNothing(postCollection(ddlMonth)) Then monthvalue = DateTime.MinValue.Month Else monthvalue = CInt(postCollection(ddlMonth))
			If String.IsNullOrEmpty(ddlDate) OrElse IsNothing(postCollection(ddlDate)) Then dayvalue = DateTime.MinValue.Day Else dayvalue = CInt(postCollection(ddlDate))
			If String.IsNullOrEmpty(ddlHour) OrElse IsNothing(postCollection(ddlHour)) Then
				hourvalue = DateTime.MinValue.Hour
			Else
				If String.IsNullOrEmpty(ddlAMPM) OrElse IsNothing(postCollection(ddlAMPM)) Then
					hourvalue = CInt(postCollection(ddlHour))
				Else
					hourvalue = (CInt(postCollection(ddlHour)) Mod 12) + CInt(postCollection(ddlAMPM))
				End If
			End If
			If String.IsNullOrEmpty(ddlMinute) OrElse IsNothing(postCollection(ddlMinute)) Then minutevalue = DateTime.MinValue.Minute Else minutevalue = CInt(postCollection(ddlMinute))
			If String.IsNullOrEmpty(ddlSecond) OrElse IsNothing(postCollection(ddlSecond)) Then secondvalue = DateTime.MinValue.Second Else secondvalue = CInt(postCollection(ddlSecond))
			Me.SelectedDateTime = New DateTime(yearvalue, monthvalue, dayvalue, hourvalue, minutevalue, secondvalue)

			Return prevdatetime <> Me.SelectedDateTime
		End Function

		Public Sub RaisePostDataChangedEvent() Implements System.Web.UI.IPostBackDataHandler.RaisePostDataChangedEvent
			RaiseEvent SelectedDateTimeChanged(Me, System.EventArgs.Empty)
		End Sub

		Private Sub Ctrl_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.PreRender
			Me.EnsureChildControls()
			Dim ctrls As IEnumerator = Me.Controls.GetEnumerator()
			Dim ddlYear, ddlMonth, ddlDate, ddlHour, ddlMinute, ddlSecond, ddlAMPM, temp As DropDownList

			'Populate existing DropDownLists
			While ctrls.MoveNext()
				If ctrls.Current.GetType() Is GetType(DropDownList) Then
					temp = CType(ctrls.Current, DropDownList)
					Select Case temp.ID
						Case "ddlYear" : ddlYear = temp
							Me.FirstYear = Math.Min(Me.SelectedDateTime.Year, Me.FirstYear)
							Me.LastYear = Math.Max(Me.SelectedDateTime.Year, Me.LastYear)
							temp.Items.Clear()
							For i As Integer = Me.FirstYear To Me.LastYear
								temp.Items.Add(i.ToString())
							Next
						Case "ddlMonth" : ddlMonth = temp
							temp.Items.Clear()
							For i As Integer = 1 To 12
								Select Case Me.MonthFormat
									Case MonthNameStyle.Abbreviated : temp.Items.Add(New ListItem(System.Globalization.DateTimeFormatInfo.CurrentInfo.GetAbbreviatedMonthName(i), i.ToString()))
									Case MonthNameStyle.Full : temp.Items.Add(New ListItem(System.Globalization.DateTimeFormatInfo.CurrentInfo.GetMonthName(i), i.ToString()))
									Case MonthNameStyle.Numeric : temp.Items.Add(i.ToString())
								End Select
							Next
						Case "ddlDate" : ddlDate = temp
							Dim day As String = String.Empty
							temp.Items.Clear()
							For i As Integer = 1 To DateTime.DaysInMonth(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month)
								Select Case Me.DayFormat
									Case DayNameStyle.FirstLetter : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString().Substring(0, 1)
									Case DayNameStyle.FirstTwoLetters : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString().Substring(0, 2)
									Case DayNameStyle.Full : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString()
									Case DayNameStyle.None : day = String.Empty
									Case DayNameStyle.Short : day = System.Globalization.DateTimeFormatInfo.CurrentInfo.AbbreviatedDayNames(New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek)
								End Select
								temp.Items.Add(New ListItem(String.Format("{0} {1}", day, i).TrimStart(" "c), i.ToString()))
							Next
						Case "ddlHour" : ddlHour = temp
						Case "ddlMinute" : ddlMinute = temp
							temp.Items.Clear()
							For i As Byte = 0 To 59
								temp.Items.Add(i.ToString("00"))
							Next
						Case "ddlSecond" : ddlSecond = temp
							temp.Items.Clear()
							For i As Byte = 0 To 59
								temp.Items.Add(i.ToString("00"))
							Next
						Case "ddlAMPM" : ddlAMPM = temp
							temp.Items.Clear()
							temp.Items.Add(New ListItem("AM", "0"))
							temp.Items.Add(New ListItem("PM", "12"))
					End Select
				End If
			End While

			'Populate ddlHour DropDownList
			If Not IsNothing(ddlHour) Then
				ddlHour.Items.Clear()
				If IsNothing(ddlAMPM) Then
					For i As Byte = 0 To 23
						ddlHour.Items.Add(i.ToString())
					Next
				Else
					For i As Byte = 1 To 12
						ddlHour.Items.Add(i.ToString())
					Next
				End If
			End If

			'Select correct items in existing DropDownLists
			If Not IsNothing(ddlAMPM) Then ddlAMPM.SelectedIndex = CInt(Math.Floor(Me.SelectedDateTime.Hour / 12))
			If Not IsNothing(ddlHour) Then If IsNothing(ddlAMPM) Then ddlHour.SelectedIndex = Me.SelectedDateTime.Hour Else ddlHour.SelectedIndex = (Me.SelectedDateTime.Hour + 11) Mod 12
			If Not IsNothing(ddlMinute) Then ddlMinute.SelectedIndex = Me.SelectedDateTime.Minute
			If Not IsNothing(ddlSecond) Then ddlSecond.SelectedIndex = Me.SelectedDateTime.Second
			If Not IsNothing(ddlYear) Then ddlYear.SelectedValue = Me.SelectedDateTime.Year.ToString()
			If Not IsNothing(ddlMonth) Then ddlMonth.SelectedIndex = Me.SelectedDateTime.Month - 1
			If Not IsNothing(ddlDate) Then ddlDate.SelectedIndex = Me.SelectedDateTime.Day - 1

			If Not (IsNothing(ddlYear) OrElse IsNothing(ddlMonth) OrElse IsNothing(ddlDate)) Then
				Me.Page.RegisterRequiresPostBack(Me)
				Dim arg As String = String.Format("document.getElementById('{0}').value+' '+document.getElementById('{1}').value+' '+document.getElementById('{2}').value", ddlYear.ClientID, ddlMonth.ClientID, ddlDate.ClientID)
				Dim callback As String = Me.Page.ClientScript.GetCallbackEventReference(Me, arg, "UpdateDateTimePicker", Nothing)
				ddlMonth.Attributes.Add("onchange", callback)
				ddlYear.Attributes.Add("onchange", callback)

				If Not Me.Page.ClientScript.IsClientScriptBlockRegistered("UpdateDateTimePicker") Then
					Dim clientupdater As New System.Text.StringBuilder("function UpdateDateTimePicker(datedata){")
					clientupdater.Append("var datedataparts=datedata.split('|');")
					clientupdater.Append("var dayddl=document.getElementById(datedataparts[0]);")
					clientupdater.Append("dayddl.length=0;")
					clientupdater.Append("for(x=0;x<parseInt(datedataparts[2]);x++){dayddl.options[x]=new Option(datedataparts[x%7+3]+(x+1),x+1);}")
					clientupdater.Append("dayddl.selectedIndex=parseInt(datedataparts[1]);")
					clientupdater.Append("}")
					Me.Page.ClientScript.RegisterClientScriptBlock(Me.GetType(), "UpdateDateTimePicker", clientupdater.ToString(), True)
				End If
			End If
		End Sub

		Public Enum DayNameStyle As Byte
			None
			Full
			[Short]
			FirstLetter
			FirstTwoLetters
		End Enum
		Public Enum MonthNameStyle As Byte
			Full
			Abbreviated
			Numeric
		End Enum
		Public Enum DTPLayout As Byte
			DateTime2Line
			TimeDate2Line
			[Date]
			Time
			DateTime1Line
			TimeDate1Line
		End Enum
	End Class

	Namespace DateTimePickerTemplates
		Public Class DateTime2LineTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlMonth As New DropDownList()
				ddlMonth.ID = "ddlMonth"
				container.Controls.Add(ddlMonth)
				Dim ddlDate As New DropDownList()
				ddlDate.ID = "ddlDate"
				container.Controls.Add(ddlDate)
				Dim ddlYear As New DropDownList()
				ddlYear.ID = "ddlYear"
				container.Controls.Add(ddlYear)
				container.Controls.Add(New LiteralControl("<br/>"))
				Dim ddlHour As New DropDownList()
				ddlHour.ID = "ddlHour"
				container.Controls.Add(ddlHour)
				Dim ddlMinute As New DropDownList()
				ddlMinute.ID = "ddlMinute"
				container.Controls.Add(ddlMinute)
				Dim ddlSecond As New DropDownList()
				ddlSecond.ID = "ddlSecond"
				container.Controls.Add(ddlSecond)
				Dim ddlAMPM As New DropDownList()
				ddlAMPM.ID = "ddlAMPM"
				container.Controls.Add(ddlAMPM)
			End Sub
		End Class
		Public Class TimeDate2LineTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlHour As New DropDownList()
				ddlHour.ID = "ddlHour"
				container.Controls.Add(ddlHour)
				Dim ddlMinute As New DropDownList()
				ddlMinute.ID = "ddlMinute"
				container.Controls.Add(ddlMinute)
				Dim ddlSecond As New DropDownList()
				ddlSecond.ID = "ddlSecond"
				container.Controls.Add(ddlSecond)
				Dim ddlAMPM As New DropDownList()
				ddlAMPM.ID = "ddlAMPM"
				container.Controls.Add(ddlAMPM)
				container.Controls.Add(New LiteralControl("<br/>"))
				Dim ddlMonth As New DropDownList()
				ddlMonth.ID = "ddlMonth"
				container.Controls.Add(ddlMonth)
				Dim ddlDate As New DropDownList()
				ddlDate.ID = "ddlDate"
				container.Controls.Add(ddlDate)
				Dim ddlYear As New DropDownList()
				ddlYear.ID = "ddlYear"
				container.Controls.Add(ddlYear)
			End Sub
		End Class
		Public Class DateTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlMonth As New DropDownList()
				ddlMonth.ID = "ddlMonth"
				container.Controls.Add(ddlMonth)
				Dim ddlDate As New DropDownList()
				ddlDate.ID = "ddlDate"
				container.Controls.Add(ddlDate)
				Dim ddlYear As New DropDownList()
				ddlYear.ID = "ddlYear"
				container.Controls.Add(ddlYear)
			End Sub
		End Class
		Public Class TimeTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlHour As New DropDownList()
				ddlHour.ID = "ddlHour"
				container.Controls.Add(ddlHour)
				Dim ddlMinute As New DropDownList()
				ddlMinute.ID = "ddlMinute"
				container.Controls.Add(ddlMinute)
				Dim ddlSecond As New DropDownList()
				ddlSecond.ID = "ddlSecond"
				container.Controls.Add(ddlSecond)
				Dim ddlAMPM As New DropDownList()
				ddlAMPM.ID = "ddlAMPM"
				container.Controls.Add(ddlAMPM)
			End Sub
		End Class
		Public Class DateTime1LineTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlMonth As New DropDownList()
				ddlMonth.ID = "ddlMonth"
				container.Controls.Add(ddlMonth)
				Dim ddlDate As New DropDownList()
				ddlDate.ID = "ddlDate"
				container.Controls.Add(ddlDate)
				Dim ddlYear As New DropDownList()
				ddlYear.ID = "ddlYear"
				container.Controls.Add(ddlYear)
				Dim ddlHour As New DropDownList()
				ddlHour.ID = "ddlHour"
				container.Controls.Add(ddlHour)
				Dim ddlMinute As New DropDownList()
				ddlMinute.ID = "ddlMinute"
				container.Controls.Add(ddlMinute)
				Dim ddlSecond As New DropDownList()
				ddlSecond.ID = "ddlSecond"
				container.Controls.Add(ddlSecond)
				Dim ddlAMPM As New DropDownList()
				ddlAMPM.ID = "ddlAMPM"
				container.Controls.Add(ddlAMPM)
			End Sub
		End Class
		Public Class TimeDate1LineTemplate : Implements ITemplate
			Public Sub InstantiateIn(ByVal container As System.Web.UI.Control) Implements System.Web.UI.ITemplate.InstantiateIn
				Dim ddlHour As New DropDownList()
				ddlHour.ID = "ddlHour"
				container.Controls.Add(ddlHour)
				Dim ddlMinute As New DropDownList()
				ddlMinute.ID = "ddlMinute"
				container.Controls.Add(ddlMinute)
				Dim ddlSecond As New DropDownList()
				ddlSecond.ID = "ddlSecond"
				container.Controls.Add(ddlSecond)
				Dim ddlAMPM As New DropDownList()
				ddlAMPM.ID = "ddlAMPM"
				container.Controls.Add(ddlAMPM)
				Dim ddlMonth As New DropDownList()
				ddlMonth.ID = "ddlMonth"
				container.Controls.Add(ddlMonth)
				Dim ddlDate As New DropDownList()
				ddlDate.ID = "ddlDate"
				container.Controls.Add(ddlDate)
				Dim ddlYear As New DropDownList()
				ddlYear.ID = "ddlYear"
				container.Controls.Add(ddlYear)
			End Sub
		End Class
	End Namespace
End Namespace