DateTimePicker Control

DateTimePicker.vb:
Namespace NathanSokalski
	Public Class DateTimePicker : Inherits System.Web.UI.WebControls.CompositeControl : Implements ICallbackEventHandler, IPostBackDataHandler
		Private ddlMonth, ddlDate, ddlYear, ddlHour, ddlMinute, ddlSecond, ddlAMPM As DropDownList
		Private _firstyear As Integer = 1950
		Private _lastyear As Integer = 2050
		Private _dayformat As DayNameStyle = DayNameStyle.None
		Private _monthformat As MonthNameStyle = MonthNameStyle.Abbreviated
		Private _layout As DTPLayout = DTPLayout.DateTime2Line
		Private _use24hourformat As Boolean = False
		Private _displayseconds As Boolean = True
		Private passedvalue As String = String.Empty
		Public Event SelectedDateTimeChanged As EventHandler

		<Description("The currently selected date and time")> Public Property SelectedDateTime() As DateTime
			Get
				If IsNothing(Me.ViewState("SelectedDateTime")) Then Return DateTime.Now Else Return CDate(Me.ViewState("SelectedDateTime"))
			End Get
			Set(ByVal value As DateTime)
				Me.ViewState("SelectedDateTime") = value
			End Set
		End Property
		<DefaultValue(1950), _
		Description("The first year displayed in the year DropDownList")> _
		Public Property FirstYear() As Integer
			Get
				Return Me._firstyear
			End Get
			Set(ByVal value As Integer)
				Me._firstyear = value
			End Set
		End Property
		<DefaultValue(2050), _
		Description("The last year displayed in the year DropDownList")> _
		Public Property LastYear() As Integer
			Get
				Return Me._lastyear
			End Get
			Set(ByVal value As Integer)
				Me._lastyear = value
			End Set
		End Property
		<DefaultValue("None"), _
		Description("The format of the day of the week in the day DropDownList")> _
		Public Property DayFormat() As DayNameStyle
			Get
				Return Me._dayformat
			End Get
			Set(ByVal value As DayNameStyle)
				Me._dayformat = value
			End Set
		End Property
		<DefaultValue("Abbreviated"), _
		Description("The format of the month in the month DropDownList")> _
		Public Property MonthFormat() As MonthNameStyle
			Get
				Return Me._monthformat
			End Get
			Set(ByVal value As MonthNameStyle)
				Me._monthformat = value
			End Set
		End Property
		<DefaultValue("DateTime2Line"), _
		Description("The layout of the date and/or time DropDownLists")> _
		Public Property Layout() As DTPLayout
			Get
				Return Me._layout
			End Get
			Set(ByVal value As DTPLayout)
				Me._layout = value
			End Set
		End Property
		<DefaultValue(False), _
		Description("A Boolean value specifying whether the time should be displayed using 12 hour (am/pm) or 24 hour format")> _
		Public Property Use24HourFormat() As Boolean
			Get
				Return Me._use24hourformat
			End Get
			Set(ByVal value As Boolean)
				Me._use24hourformat = value
			End Set
		End Property
		<DefaultValue(True), _
		Description("A Boolean value specifying whether the seconds DropDownList should be displayed")> _
		Public Property DisplaySeconds() As Boolean
			Get
				Return Me._displayseconds
			End Get
			Set(ByVal value As Boolean)
				Me._displayseconds = value
			End Set
		End Property
		Public ReadOnly Property LayoutIncludesDate() As Boolean
			Get
				Return Me.Layout <> DTPLayout.Time
			End Get
		End Property
		Public ReadOnly Property LayoutIncludesTime() As Boolean
			Get
				Return Me.Layout <> DTPLayout.Date
			End Get
		End Property

		Private Sub RenderDateDropDownLists(ByVal writer As System.Web.UI.HtmlTextWriter)
			Me.ddlMonth.RenderControl(writer)
			Me.ddlDate.RenderControl(writer)
			Me.ddlYear.RenderControl(writer)
		End Sub
		Private Sub RenderTimeDropDownLists(ByVal writer As System.Web.UI.HtmlTextWriter)
			Me.ddlHour.RenderControl(writer)
			Me.ddlMinute.RenderControl(writer)
			If Me.DisplaySeconds Then Me.ddlSecond.RenderControl(writer)
			If Not Me.Use24HourFormat Then Me.ddlAMPM.RenderControl(writer)
		End Sub
		Private Sub PopulateDateDropDownLists()
			Me.EnsureChildControls()
			Me.FirstYear = Math.Min(Me.SelectedDateTime.Year, Me.FirstYear)
			Me.LastYear = Math.Max(Me.SelectedDateTime.Year, Me.LastYear)
			For i As Integer = Me.FirstYear To Me.LastYear
				Me.ddlYear.Items.Add(i.ToString())
			Next

			For i As Integer = 1 To 12
				Select Case Me.MonthFormat
					Case MonthNameStyle.Abbreviated : Me.ddlMonth.Items.Add(New ListItem(System.Globalization.DateTimeFormatInfo.CurrentInfo.GetAbbreviatedMonthName(i), i.ToString()))
					Case MonthNameStyle.Full : Me.ddlMonth.Items.Add(New ListItem(System.Globalization.DateTimeFormatInfo.CurrentInfo.GetMonthName(i), i.ToString()))
					Case MonthNameStyle.Numeric : Me.ddlMonth.Items.Add(i.ToString())
				End Select
			Next

			Dim day As String = String.Empty
			Me.ddlDate.Items.Clear()
			For i As Integer = 1 To DateTime.DaysInMonth(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month)
				Select Case Me.DayFormat
					Case DayNameStyle.FirstLetter : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString().Substring(0, 1)
					Case DayNameStyle.FirstTwoLetters : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString().Substring(0, 2)
					Case DayNameStyle.Full : day = New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek.ToString()
					Case DayNameStyle.None : day = String.Empty
					Case DayNameStyle.Short : day = System.Globalization.DateTimeFormatInfo.CurrentInfo.AbbreviatedDayNames(New DateTime(Me.SelectedDateTime.Year, Me.SelectedDateTime.Month, i).DayOfWeek)
				End Select
				Me.ddlDate.Items.Add(New ListItem(String.Format("{0} {1}", day, i).TrimStart(" "c), i.ToString()))
			Next
		End Sub
		Private Sub PopulateTimeDropDownLists()
			Me.EnsureChildControls()
			If Me.Use24HourFormat Then
				For i As Byte = 0 To 23
					Me.ddlHour.Items.Add(i.ToString())
				Next
			Else
				For i As Byte = 1 To 12
					Me.ddlHour.Items.Add(i.ToString())
				Next
				Me.ddlAMPM.Items.Add(New ListItem("AM", "0"))
				Me.ddlAMPM.Items.Add(New ListItem("PM", "12"))
			End If
			For i As Byte = 0 To 59
				Me.ddlMinute.Items.Add(i.ToString("00"))
			Next
			If Me.DisplaySeconds Then
				For i As Byte = 0 To 59
					Me.ddlSecond.Items.Add(i.ToString("00"))
				Next
			End If
		End Sub
		Private Sub SelectDropDownListItems()
			If Me.LayoutIncludesTime Then
				'Set time DropDownLists
				If Me.Use24HourFormat Then
					Me.ddlHour.SelectedIndex = Me.SelectedDateTime.Hour
				Else
					Me.ddlHour.SelectedIndex = (Me.SelectedDateTime.Hour + 11) Mod 12
					Me.ddlAMPM.SelectedIndex = CInt(Math.Floor(Me.SelectedDateTime.Hour / 12))
				End If
				Me.ddlMinute.SelectedIndex = Me.SelectedDateTime.Minute
				If Me.DisplaySeconds Then Me.ddlSecond.SelectedIndex = Me.SelectedDateTime.Second
			End If

			If Me.LayoutIncludesDate Then
				'Set date DropDownLists
				Me.ddlYear.SelectedValue = Me.SelectedDateTime.Year.ToString()
				Me.ddlMonth.SelectedIndex = Me.SelectedDateTime.Month - 1
				Me.ddlDate.SelectedIndex = Me.SelectedDateTime.Day - 1
			End If
		End Sub

		Protected Overrides ReadOnly Property TagKey() As System.Web.UI.HtmlTextWriterTag
			Get
				Return HtmlTextWriterTag.Div
			End Get
		End Property
		Protected Overrides Sub AddAttributesToRender(ByVal writer As System.Web.UI.HtmlTextWriter)
			writer.AddStyleAttribute(HtmlTextWriterStyle.Display, "inline")
			writer.AddStyleAttribute(HtmlTextWriterStyle.Padding, "0px")
			writer.AddStyleAttribute(HtmlTextWriterStyle.WhiteSpace, "nowrap")
			MyBase.AddAttributesToRender(writer)
		End Sub

		Protected Overrides Sub CreateChildControls()
			Me.ddlYear = New DropDownList()
			Me.ddlYear.ID = "ddlYear"
			Me.Controls.Add(Me.ddlYear)
			Me.ddlMonth = New DropDownList()
			Me.ddlMonth.ID = "ddlMonth"
			Me.Controls.Add(Me.ddlMonth)
			Me.ddlDate = New DropDownList()
			Me.ddlDate.ID = "ddlDate"
			Me.Controls.Add(Me.ddlDate)
			Me.ddlAMPM = New DropDownList()
			Me.ddlAMPM.ID = "ddlAMPM"
			Me.Controls.Add(Me.ddlAMPM)
			Me.ddlHour = New DropDownList()
			Me.ddlHour.ID = "ddlHour"
			Me.Controls.Add(Me.ddlHour)
			Me.ddlMinute = New DropDownList()
			Me.ddlMinute.ID = "ddlMinute"
			Me.Controls.Add(Me.ddlMinute)
			Me.ddlSecond = New DropDownList()
			Me.ddlSecond.ID = "ddlSecond"
			Me.Controls.Add(Me.ddlSecond)
		End Sub

		Protected Overrides Sub RenderContents(ByVal writer As System.Web.UI.HtmlTextWriter)
			If Me.LayoutIncludesDate Then Me.PopulateDateDropDownLists()
			If Me.LayoutIncludesTime Then Me.PopulateTimeDropDownLists()
			Me.SelectDropDownListItems()

			Select Case Me.Layout
				Case DTPLayout.Date
					Me.RenderDateDropDownLists(writer)
				Case DTPLayout.DateTime1Line
					Me.RenderDateDropDownLists(writer)
					Me.RenderTimeDropDownLists(writer)
				Case DTPLayout.DateTime2Line
					Me.RenderDateDropDownLists(writer)
					writer.WriteBreak()
					Me.RenderTimeDropDownLists(writer)
				Case DTPLayout.Time
					Me.RenderTimeDropDownLists(writer)
				Case DTPLayout.TimeDate1Line
					Me.RenderTimeDropDownLists(writer)
					Me.RenderDateDropDownLists(writer)
				Case DTPLayout.TimeDate2Line
					Me.RenderTimeDropDownLists(writer)
					writer.WriteBreak()
					Me.RenderDateDropDownLists(writer)
			End Select
		End Sub

		Public Function GetCallbackResult() As String Implements System.Web.UI.ICallbackEventHandler.GetCallbackResult
			'To Browser:	id|index|daycount|day1fmt|day2fmt|day3fmt|day4fmt|day5fmt|day6fmt|day7fmt
			'To Server:		yearval monthval dayval
			Dim ymdvalues() As String = Me.passedvalue.Split(" "c)
			Dim daycount As Integer = DateTime.DaysInMonth(CInt(ymdvalues(0)), CInt(ymdvalues(1)))
			Dim datedata As New Collections.Generic.List(Of String)
			datedata.Add(Me.ddlDate.ClientID)
			datedata.Add((Math.Min(CInt(ymdvalues(2)), daycount) - 1).ToString())
			datedata.Add(daycount.ToString())
			For i As Integer = 1 To 7
				Select Case Me.DayFormat
					Case DayNameStyle.FirstLetter : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString().Substring(0, 1), " "))
					Case DayNameStyle.FirstTwoLetters : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString().Substring(0, 2), " "))
					Case DayNameStyle.Full : datedata.Add(String.Concat(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek.ToString(), " "))
					Case DayNameStyle.None : datedata.Add(String.Empty)
					Case DayNameStyle.Short : datedata.Add(String.Concat(System.Globalization.DateTimeFormatInfo.CurrentInfo.AbbreviatedDayNames(New DateTime(CInt(ymdvalues(0)), CInt(ymdvalues(1)), i).DayOfWeek), " "))
				End Select
			Next
			Return String.Join("|", datedata.ToArray())
		End Function

		Public Sub RaiseCallbackEvent(ByVal eventArgument As String) Implements System.Web.UI.ICallbackEventHandler.RaiseCallbackEvent
			Me.passedvalue = eventArgument
		End Sub

		Private Sub Ctrl_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.PreRender
			'To Browser:	id|index|daycount|day1fmt|day2fmt|day3fmt|day4fmt|day5fmt|day6fmt|day7fmt
			'To Server:		yearval monthval dayval
			If Me.LayoutIncludesDate Then
				Me.Page.RegisterRequiresPostBack(Me)

				Dim arg As String = String.Format("document.getElementById('{0}').value+' '+document.getElementById('{1}').value+' '+document.getElementById('{2}').value", Me.ddlYear.ClientID, Me.ddlMonth.ClientID, Me.ddlDate.ClientID)
				Dim callback As String = Me.Page.ClientScript.GetCallbackEventReference(Me, arg, "UpdateDateTimePicker", Nothing)
				Me.ddlMonth.Attributes.Add("onchange", callback)
				Me.ddlYear.Attributes.Add("onchange", callback)

				If Not Me.Page.ClientScript.IsClientScriptBlockRegistered("UpdateDateTimePicker") Then
					Dim clientupdater As New System.Text.StringBuilder("function UpdateDateTimePicker(datedata){")
					clientupdater.Append("var datedataparts=datedata.split('|');")
					clientupdater.Append("var dayddl=document.getElementById(datedataparts[0]);")
					clientupdater.Append("dayddl.length=0;")
					clientupdater.Append("for(x=0;x<parseInt(datedataparts[2]);x++){dayddl.options[x]=new Option(datedataparts[x%7+3]+(x+1),x+1);}")
					clientupdater.Append("dayddl.selectedIndex=parseInt(datedataparts[1]);")
					clientupdater.Append("}")
					Me.Page.ClientScript.RegisterClientScriptBlock(Me.GetType(), "UpdateDateTimePicker", clientupdater.ToString(), True)
				End If
			End If
		End Sub

		Public Function LoadPostData(ByVal postDataKey As String, ByVal postCollection As System.Collections.Specialized.NameValueCollection) As Boolean Implements System.Web.UI.IPostBackDataHandler.LoadPostData
			Dim temp As DateTime = Me.SelectedDateTime
			'Set SelectedDateTime
			Dim hastime As Boolean = Not IsNothing(postCollection(Me.ddlHour.UniqueID))
			Dim hasdate As Boolean = Not IsNothing(postCollection(Me.ddlYear.UniqueID))
			Dim hours, seconds As Integer
			If hastime Then
				If IsNothing(postCollection(Me.ddlAMPM.UniqueID)) Then hours = CInt(postCollection(Me.ddlHour.UniqueID)) Else hours = (CInt(postCollection(Me.ddlHour.UniqueID)) Mod 12) + CInt(postCollection(Me.ddlAMPM.UniqueID))
				If Not IsNothing(postCollection(Me.ddlSecond.UniqueID)) Then seconds = CInt(postCollection(Me.ddlSecond.UniqueID))
			End If
			If hasdate AndAlso Not hastime Then
				Me.SelectedDateTime = New DateTime(CInt(postCollection(Me.ddlYear.UniqueID)), CInt(postCollection(Me.ddlMonth.UniqueID)), CInt(postCollection(Me.ddlDate.UniqueID)))
			ElseIf hastime AndAlso Not hasdate Then
				Me.SelectedDateTime = New DateTime(DateTime.MinValue.Year, DateTime.MinValue.Month, DateTime.MinValue.Day, hours, CInt(postCollection(Me.ddlMinute.UniqueID)), seconds)
			ElseIf hasdate AndAlso hastime Then
				Me.SelectedDateTime = New DateTime(CInt(postCollection(Me.ddlYear.UniqueID)), CInt(postCollection(Me.ddlMonth.UniqueID)), CInt(postCollection(Me.ddlDate.UniqueID)), hours, CInt(postCollection(Me.ddlMinute.UniqueID)), seconds)
			End If

			Return temp <> Me.SelectedDateTime
		End Function

		Public Sub RaisePostDataChangedEvent() Implements System.Web.UI.IPostBackDataHandler.RaisePostDataChangedEvent
			RaiseEvent SelectedDateTimeChanged(Me, System.EventArgs.Empty)
		End Sub

		Public Enum DayNameStyle As Byte
			None
			Full
			[Short]
			FirstLetter
			FirstTwoLetters
		End Enum
		Public Enum MonthNameStyle As Byte
			Full
			Abbreviated
			Numeric
		End Enum
		Public Enum DTPLayout As Byte
			DateTime2Line
			TimeDate2Line
			[Date]
			Time
			DateTime1Line
			TimeDate1Line
		End Enum
	End Class
End Namespace